Selasa, 24 Desember 2013

LCD 2 x 16 KARAKTER

Posted by Nurvita Abrina On 06.25 | No comments
TUJUAN:
 1. Mahasiswa memahami rangkaian interface mikrokontroller dengan LCD Karakter  
     2 x 16 
 2. Mahasiswa dapat memahami program assembly untuk menampilkan 
     data ke LCD Karakter 2 x 16 
 3. Mahasiswa memahami beberapa instruksi assembly dasar, MOV, Setb, Clr, dan              waktu tunda. 4. Mahasiswa memahami mencetak karakter pada posisi baris dan            kolom tertentu


Gambar 4.1. Rangkaian interface ke LCD Karakter 2 x16
Modul LCD Character dapat dengan mudah dihubungkan dengan mikrokontroller seperti AT89S51. LCD yang akan kita praktikumkan ini mempunyai lebar display 2 baris 16 kolom atau biasa disebut sebagai LCD Character 2x16, dengan 16 pin konektor, yang didifinisikan sebagai berikut:

Display karakter pada LCD diatur oleh pin EN, RS dan RW: Jalur EN dinamakan Enable. Jalur ini digunakan untuk memberitahu LCD bahwa anda sedang mengirimkan sebuah data. Untuk mengirimkan data ke LCD, maka melalui program EN harus dibuat logika low “0” dan set pada dua jalur kontrol yang lain RS dan RW. Ketika dua jalur yang lain telah siap, set EN dengan logika “1” dan tunggu untuk sejumlah waktu tertentu ( sesuai dengan datasheet dari LCD tersebut ) dan berikutnya set EN ke logika low “0” lagi.
Jalur RS adalah jalur Register Select. Ketika RS berlogika low “0”, data akan dianggap sebagi sebua perintah atau instruksi khusus ( seperti clear screen, posisi kursor dll ). Ketika RS berlogika high “1”, data yang dikirim adalah data text yang akan ditampilkan pada display LCD. Sebagai contoh, untuk menampilkan huruf “T” pada layar LCD maka RS harus diset logika high “1”.

Jalur RW adalah jalur kontrol Read/ Write. Ketika RW berlogika low (0), maka informasi pada bus data akan dituliskan pada layar LCD. Ketika RW berlogika high ”1”, maka program akan melakukan pembacaan memori dari LCD. Sedangkan pada aplikasi umum pin RW selalu diberi logika low ”0”. Pada akhirnya, bus data terdiri dari 4 atau 8 jalur ( bergantung pada mode operasi yang dipilih oleh user ). Pada kasus bus data 8 bit, jalur diacukan sebagai DB0 s/d DB7 Beberapa perintah dasar yang harus dipahami adalah inisialisasi LCD Character,
CATATAN:
 X : Don‟t care 
DL: Mengatur lebar data 
DL=1, Lebar data interface 8 bit ( DB7 s/d DB0) 
DL=0, Lebar data interface 4 bit ( DB7 s/d DB4)
Ketika menggunakan lebar data 4 bit, data harus dikirimkan dua kali 
N: Pengaktivan baris 
N=0, 1 baris 
N=1, 2 baris 
F: Penentuan ukuran font karakter
F=0, 5x7
F=1, 5x8







Catatan: 

I/D: Increment/ decrement dari alamat DDRAM dengan 1 ketika kode karakter dituliskan ke DDRAM.
I/D = “0”, decrement
I/D= “1”, increment
S: Geser keseluruhan display kekanan dan kekiri
S=1, geser kekiri atau kekanan bergantung pada I/D
S=0, display tidak bergeser








 D : Mengatur display

 D = 1,Display is ON
 D = 0, Display is OFF
          Pada kasus ini data display masih tetap berada di DDRAM, dan dapat ditampilkan kembali           secara langsung dengan mengatur D=1.


C : Menampilkan kursor 
C = 1, kursor ditampilkan
C = 0, kursor tidak ditampilkan 
B : Karakter ditunjukkan dengan kursor yang berkedip
B=1, kursor blink












Pada peta memori tersebut, daerah yang berwarna biru ( 00 s/d 0F dan 40 s/d 4F ) adalah display yang tampak. Sebagaimanan yang anda lihat, jumlahnya sebanyak 16 karakter per baris dengan dua baris. Angka pada setiap kotak adalah alamat memori yang bersesuaian dengan posisi dari layar. Demikianlah karakter pertama di sudut kiri atas adalah menempati alamah 00h. Posisi karakter berikutnya adalah alamat 01h dan seterusnya.
Akan tetapi, karakter pertama dari baris 2 sebagaimana yang ditunjukkan pada peta memori adalah pada alamat 40h. Dimikianlah kita perlu untuk mengirim sebuah perintah ke LCD untuk mangatur letak posisi kursor pada baris dan kolom tertentu. Instruksi Set Posisi Kursor adalah 80h. Untuk ini kita perlu menambahkan alamat lokasi dimana kita berharap untuk menempatkan kursor.Sebagai contoh, kita ingin menampilkan kata ”World” pada baris ke dua pada posisi kolom ke sepuluh. Sesuai peta memori, posisi karakter pada kolom 11 dari baris ke dua, mempunyai alamat 4Ah, sehingga sebelum kita tulis kata ”World” pada LCD, kita harus mengirim instruksi set posisi kursor, dan perintah untuk instruksi ini adalah 80h ditambah dengan alamat 80h+4Ah =0Cah. Sehingga dengan mengirim perintah Cah ke LCD, akan menempatkan kursor pada baris kedua dan kolom ke 11 dari DDRAM.


INISIALISASI 
Sebelum kita dapat menggunakan modul LCD, kita harus melakukan inisialisasi dan mengkonfigurasikannya. Hal ini dijalankan dengan mengirimkan sejumlah instruksi ke LCD. Antara lain: pengaturan lebar data interface 8 bit atau 4 bit data bus, pemilihan ukuran font karakter 5x8 atau 5x7 dan lain-lain, dengan instruksi sebagai berikut.

Init_lcd:

mov r1,#00000001b ;Display clear
call write_inst ;EN=pulse dan RS=0
mov r1,#00111000b ;Function set, ;Data 8 bit,2 line font 5x7
call write_inst ;Set bit EN=pulse dan RS=0
mov r1,#00001100b ;Display on, ;cursor off,cursor blink off
call write_inst ;EN=pulse dan RS=0
mov r1,#00000110b ;Entry mode, Set increment
call write_inst
ret
end

PERCOBAAN 1. TULIS SEBUAH KARAKTER PADA LCD KARAKTER

Pada percobaan ini, karakter „A‟ akan ditampilkan pada 7 Segmen Display 1 Untuk melakukan percobaan ini lakukan beberapa langkah sebagai berikut: 
1. Pasang jumper LCD_EN, yang berfungsi untuk memberikan power supply +5V
2. Hubungkan modul Microcontroller Trainer dengan power supply +5V
3. Hubungkan modul Microcontroller Trainer dengan rangkaian programmer 
4. Buka Program M-IDE Studio for MCS-51, sebagai editor dan compiler program
5. Ketik program berikut ini:

org 0h

call init_LCD
start: mov R1,#80h ; Lokasi Display RAM, Row=1 Col=1
call write_inst
mov R1,#'A' ; Cetak Karakter A
call write_data
stop: sjmp stop

Init_lcd:

mov r1,#00000001b ;Display clear
call write_inst
mov r1,#00111000b ;Function set,Data 8 bit,2 line font 5x7
call write_inst
mov r1,#00001100b ;Display on, ;cursor off,cursor blink off
call write_inst
mov r1,#00000110b ;Entry mode, Set increment
call write_inst
ret
;
Write_inst:
clr P3.6 ; P3.6 = RS =0
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
clr P3.7 ; P3.7 =EN = 0
ret
;
Write_data:
setb P3.6 ; P3.6 = RS =1
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
clr p3.7 ; P3.7 =EN = 0
ret
;
delay: mov R0,#0
delay1:mov R7,#0fh
djnz R7,$
djnz R0,delay1
ret
;
end


6. Simpanlah program yang anda ketik dan beri nama : prog41a.asm 
7. Pada program MIDE tersebut pilih Build /F9 atau untuk melakukan kompilasi                   program dari *.asm ke *.hex.
8. Lakukan pemrograman mikrokontroller dengan menggunakan Program ISP                   Software ( Lihat Petunjuk Penggunaan) 
9. Lakukan pengamatan pada LED. 
10. Lakukan modifikasi pada program tersebut untuk mencetak karakter lain, sesuai            tabel:




PERCOBAAN 2. TULIS DELAPAN KARAKTER PADA LCD KARAKTER

Pada percobaan ini, karakter „A‟ akan ditampilkan pada 7 Segmen Display 1 Untuk melakukan percobaan ini lakukan beberapa langkah sebagai berikut: 
1. Pasang jumper LCD_EN, yang berfungsi untuk memberikan power supply +5V 
2. Hubungkan modul Microcontroller Trainer dengan power supply +5V
3. Hubungkan modul Microcontroller Trainer dengan rangkaian programmer 
4. Buka Program M-IDE Studio for MCS-51, sebagai editor dan compiler program 
5. Ketik program berikut ini:

$mod51
org 0h

call init_LCD

start: mov R1,#80h ; Lokasi Display RAM, Row=1 Col=1
call write_inst
mov R1,#'W'
call write_data
mov R1,#'e'
call write_data
mov R1,#'l'
call write_data
mov R1,#'c'
call write_data
mov R1,#'o'
call write_data
mov R1,#'m'
call write_data
mov R1,#'e'
call write_data
stop: sjmp stop

Init_lcd:
mov r1,#00000001b ;Display clear
call write_inst
mov r1,#00111000b ;Function set, Data 8 bit,2 line font 5x7
call write_inst
mov r1,#00001100b ;Display on, cursor off,cursor blink off
call write_inst
mov r1,#00000110b ;Entry mode, Set increment
call write_inst
ret
;
Write_inst:
clr P3.6 ; P3.6 = RS =0
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
clr P3.7 ; P3.7 =EN = 0
ret
;
Write_data:
setb P3.6 ; P3.6 = RS =1
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
clr p3.7 ; P3.7 =EN = 0
ret
;
delay: mov R0,#0
delay1:mov R7,#0fh
djnz R7,$
djnz R0,delay1
ret
;
end

6. Simpanlah program yang anda ketik dan beri nama : prog42a.asm 

7. Pada program MIDE tersebut pilih Build /F9 atau untuk melakukan kompilasi                   program dari *.asm ke *.hex. 
8. Lakukan pemrograman mikrokontroller dengan menggunakan Program ISP                   Software ( Lihat Petunjuk Penggunaan) 
9. Lakukan pengamatan pada LED. 
10.Lakukan modifikasi pada program tersebut untuk mencetak karakter lain, sesuai            tabel:



PERCOBAAN 3. TULIS KARAKTER DENGAN LOOK UP TABLE

Pada percobaan ini, karakter „A‟ akan ditampilkan pada 7 Segmen Display 1 Untuk melakukan percobaan ini lakukan beberapa langkah sebagai berikut: 
1. Pasang jumper LCD_EN, yang berfungsi untuk memberikan power supply +5V
2. Hubungkan modul Microcontroller Trainer dengan power supply +5V
3. Hubungkan modul Microcontroller Trainer dengan rangkaian programmer
4. Buka Program M-IDE Studio for MCS-51, sebagai editor dan compiler program 
5. Ketik program berikut ini:

$mod51
org 0h
call init_LCD
start: call write_char
stop: sjmp stop
;
write_char:
mov dptr,#word1 ;DPTR = [ address word1 ]

mov r3,#16 ;R3=16,number character to be display

mov r1,#80h ;R1=80h,address DDRAM start position
call write_inst
;
write1:clr a ; A = 0
movc a,@a+dptr ; A = [A+ DPTR]
mov r1,A ; R1 = A
inc dptr ; DPTR = DPTR +1
call write_data;
djnz r3,write1 ; R3 = R3-1,
ret
;
Init_lcd:
mov r1,#00000001b ;Display clear
call write_inst ;
mov r1,#00111000b ;Function set, Data 8 bit,2 line font 5x7
call write_inst ;
mov r1,#00001100b ;Display on, cursor off,cursor blink off
call write_inst
mov r1,#00000110b ;Entry mode, Set increment
call write_inst
ret
;
Write_inst:
clr P3.6 ; P3.6 = RS =0
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
clr P3.7 ; P3.7 =EN = 0
ret
;
Write_data:
setb P3.6 ; P3.6 = RS =1
mov P0,R1 ; P0 = D7 s/d D0 = R1
setb P3.7 ; P3.7 =EN = 1
call delay ; call delay time
call delay ; call delay time
clr p3.7 ; P3.7 =EN = 0
ret
;
delay: mov R0,#0
delay1:mov R7,#0fh
djnz R7,$
djnz R0,delay1
ret
;
word1: DB ' Welcome Home '; Karakter yang disimpan di ROM
;
end

6. Simpanlah program yang anda ketik dan beri nama : prog43a.asm 

7. Pada program MIDE tersebut pilih Build /F9 atau untuk melakukan kompilasi                    program dari           *.asm ke *.hex. 
8. Lakukan pemrograman mikrokontroller dengan menggunakan Program ISP                   Software ( Lihat Petunjuk Penggunaan) 
9. Lakukan pengamatan pada LCD. 
10. Lakukan modifikasi pada program tersebut untuk mencetak karakter lain, sesuai            tabel:



PERCOBAAN 4. PERINTAH GESER SATU KARAKTER

 Pada percobaan ini, karakter ”A” akan ditampilkan pada layar LCD Karakter dan dilakukan proses geser ke kanan. Untuk melakukan percobaan ini lakukan beberapa langkah sebagai berikut: 
1. Pasang jumper LCD_EN, yang berfungsi untuk memberikan power supply +5V 
2. Hubungkan modul Microcontroller Trainer dengan power supply +5V 
3. Hubungkan modul Microcontroller Trainer dengan rangkaian programmer 
4. Buka Program M-IDE Studio for MCS-51, sebagai editor dan compiler program 
5. Ketik program berikut ini:

$mod51
geserL equ 00011011b ; 0 0 0 1 S/C R/L X X
geserR equ 00011111b ; 0 0 0 1 S/C R/L X X
;
org 0h
call init_LCD
start: mov R1,#80h
call write_inst
mov R1,#'A' ; Karakter yang akan digeser
call write_data
;
mov R3,#40 ; 40x geser ke kanan
Next: mov R1,#geserR
call write_inst
call ldelay
djnz R3,next
sjmp start
;
Init_lcd:
mov r1,#00000001b                    ;Display clear
call write_inst ;
mov r1,#00111000b                    ;Function set,
                                                    ;Data 8 bit,2 line font 5x7
call write_inst ;
mov r1,#00001100b                    ;Display on,;cursor off,cursor blink off
call write_inst
mov r1,#00000110b                    ;Entry mode, Set increment
call write_inst
ret
;
Write_inst:
clr P3.6 ; RS = 0, write mode instruction
mov P0,R1                                   ; D7 s/d D0 = P0 = R1
setb P3.7                                      ; EN = 1
call delay                                      ; call delay time
clr P3.7                                        ; EN = 0
ret
;
Write_data:
setb P3.6                                      ; RS = 1, write mode data
mov P0,R1                                   ; D7 s/d D0 = P0 = R1
setb P3.7                                      ; EN =1
call delay                                      ; call delay time
clr p3.7 ; EN = 0
ret
;
Ldelay: mov R2,#030h
Ld1: call delay
djnz R2,Ld1
ret
;
delay: mov R0,#0
delay1:mov R7,#0fh
djnz R7,$
djnz R0,delay1
ret
;
end

PERCOBAAN 5. PERINTAH GESER KALIMAT 

Pada percobaan ini, kalimat ”Welcome home” akan ditampilkan pada layar LCD Karakter dengan menggunakan look up table dan dilakukan proses geser ke kiri. Untuk melakukan percobaan ini lakukan beberapa langkah sebagai berikut: 
1. Pasang jumper LCD_EN, yang berfungsi untuk memberikan power supply +5V
2. Hubungkan modul Microcontroller Trainer dengan power supply +5V 
3. Hubungkan modul Microcontroller Trainer dengan rangkaian programmer 
4. Buka Program M-IDE Studio for MCS-51, sebagai editor dan compiler program 
5. Ketik program berikut ini:

$mod51
geserL equ 00011011b ; 0 0 0 1 S/C R/L X X
geserR equ 00011111b ; 0 0 0 1 S/C R/L X X
org 0h
call init_LCD
start: call write_char
call geser
sjmp start
;
geser:
mov R6,#40 ;R7 = 40    ; geser sebanyak 40 karakter
lagi: mov R1,#geserL    ;R1 = GeserLeft
call write_inst
call ldelay
djnz R6,lagi                     ;R7=R7-1, jika R7 ? 0 maka lompat ke lagi
write_char:
mov dptr,#word1             ;DPTR = [ address word1 ]
mov r3,#16                       ;R3=16,number character to be display
mov r1,#80h                     ;R1=80h,address DDRAM start position
call write_inst
;
write1:clr a                       ; A = 0


movc a,@a+dptr ; A = [A+ DPTR]
mov r1,A ; R1 = A
inc dptr ; DPTR = DPTR +1
call write_data;
djnz r3,write1 ; R3 = R3-1,
ret
;
Init_lcd:
mov r1,#00000001b ;Display clear
call write_inst ;
mov r1,#00111000b ;Function set,
;Data 8 bit,2 line font 5x7
call write_inst ;
mov r1,#00001100b ;Display on,
;cursor off,cursor blink off
call write_inst
mov r1,#00000110b ;Entry mode, Set increment
call write_inst
ret
;
Write_inst:
clr P3.6 ; RS = P2.0 = 0, write mode instruction
mov P0,R1 ; D7 s/d D0 = P0 = R1
setb P3.7 ; EN = 1 = P2.1
call delay ; call delay time
clr P3.7 ; EN = 0 = P2.1
ret
;
Write_data:
setb P3.6 ; RS = P2.0 = 1, write mode data
mov P0,R1 ; D7 s/d D0 = P0 = R1
setb P3.7 ; EN = 1 = P2.1
call delay ; call delay time
clr p3.7 ; EN = 0 = P2.1
ret
;
Ldelay: mov R2,#030h
Ld1: acall delay
djnz R2,Ld1
ret
delay: mov R0,#0
delay1: mov R7,#0fh
djnz R7,$
djnz R0,delay1
ret
;
word1: DB ' Welcome Home '; here is the data to be look up
;
end

6. Simpanlah program yang anda ketik dan beri nama : prog44a.asm 

7. Pada program MIDE tersebut pilih Build /F9 atau untuk melakukan kompilasi                   program dari *.asm ke *.hex. 
8. Lakukan pemrograman mikrokontroller dengan menggunakan Program ISP                   Software ( Lihat Petunjuk Penggunaan)


Sumber : http://guru.technosains.com/

PRAKTEK-5 Seven Segment

Posted by Nurvita Abrina On 01.51 | No comments
Langkah:
1. Hubungkan P1 DT51 MinSysn dengan “DATA 7S” DT-51 trainer board.
2. Hubungkan Port C DT51 MinSysn dengan “I/P S KEY” DT-51 trainer board.
3. Hubungkan CONTROL DT-51 Min Sys dengan CONTROL DT-51 trainer board.
4. Hubungkan DT-51 MinSys dengan PC menggunakan kabel serial
5. Hubungkan Dt-51 MInSys dengansumber tegangan

Teori

Seven segment adalah diode LED sebanyak 7 buah yang disusun dan dikemas membentuk penampil angka, dan biasanya ditambahkan 1 buah LED untuk koma (Dot Point). Karena dibentuk dari kumpulan LED maka ada dua jenis seven segment, yaitu Common Anode (CA) dan Common Catode (CC).
Untuk penyalakan seven segment jenis CC maka masukan segment a s/d Dp harus diberi logika tinggi dan bagian CC dihubungkan dengan Ground. Sedangkan jika ingin menyalakan seven segment jenis CA maka masukan segment a s/d Dp harus diberi logika LOW dan CA harus dihubungkan ke +5 VCC.



Skema Rangkaian
P1 sbg input PA sebagai output


ALAMAT PENTING MODUL DT-51 adalah sbb:
1. PA (port A) = 2000h
2. PB (port B) = 2001h
3. PC (port C) = 2002h
4. Reg CW (Control Word) = 2003h
5. DIGIT1 = 80h
6. DIGIT2 = 40h

Dari gambar rangkaian di atas saluran data tampilan angka menggunakan P1 yang dipakai bersama antara digit1 dan digit 2 sehingga jika ingin menampilkan angka bersama (tampil 2 digit sekaligus) dilakukan secara bergantian secara cepat sehingga tampil seolah-olah berbarengan. Catatan penting untuk tampilan secara bergatian dari digit1 ke digit2 harus diselingi dengan mematikan semua sesaat, karena jika tidak dimatikan sesaat maka tampilan angka akan tumpang tindih.

PROGRAM 1
;--------------------------------
; contoh scanning seven segment
; menampilkan angka 51
;--------------------------------
$mod51
PORTC EQU 2002H
CW EQU 2003H
CSEG
ORG 4000H
LJMP START

DELAY: MOV R6, #0FH
LUP: MOV R7, #0FFH
DJNZ R7, $
DJNZ R6, LUP
RET

START:
MOV SP, #30H
MOV DPTR, #CW
MOV A, #80H
MOVX @DPTR, A

LOOP:
;menampilkan angka 5 di seven segment 1
MOV DPTR, #PORTC
MOV A, #80H
MOVX @DPTR, A
MOV P1, #6DH
LCALL DELAY
MOV P1,#00H

;menampilkan angka 7 di seven segment 2
MOV A, #40H
MOVX @DPTR, A
MOV P1, #07H
LCALL DELAY
MOV P1,#00H
SJMP LOOP

END

Latihan:
Buatlah program untuk menampilkan tampilan seven segment saat awal tampil “00”, selang beberapa detik tampil angka “01”, selang beberapa detik tampil “02” dan seterusnya sampai “09” dan kembali lagi ke awal.



Langkah:
1. Hubungkan PORT DT51 MinSysn dengan PORT INPUTDT-51 trainer board.
2. Hubungkan CONTROL DT-51 Min Sys dengan CONTROL DT-51 trainer board.
3. Hubungkan DT-51 MinSys dengan PC menggunakan kabel serial
4. Hubungkan Dt-51 MInSys dengansumber tegangan

Skema Rangkaian P1 sbg input PA sebagai output



ALAMAT PORT tambahan pada system DT-51 adalah sbb:
1. PA (port A) = 2000h
2. PB (port B) = 2001h
3. PC (port C) = 2002h
4. Reg CW (Control Word) = 2003h

PA adalah PORT tambahan (eksternal) diluar mikrokontroler, yang disediakan dari IC PPI 8255. Mikrokontroler dapat menggunakan PA ini dengan cara MEMPROGRAMNYA TERLEBIH DAHULU lewat register internal PPI 8255 yaitu register CW (control word).
Contoh Memprogram semua Port PPI 8255 (PA, PB, PC) sebagai output, maka reg CW harus diberi data 80h (lihat manual PPI 8255).

KODE :
MOV DPTR,#2003H
MOV A, #80H
MOVX @DPTR,A


Program 1 LED Berpassword
% Membaca data password dari P1, jika PWD benar, LED DI PA nyala
% ==============================================================

$mod51
PWD EQU 22H
CW EQU 2003h
CSEG
ORG 4000H
LJMP START
ORG 4100H

START:
MOV SP, #30H

INIT: 
MOV DPTR, #CW ; proses isi cw dg data 80H
MOV A, #80H
MOVX @DPTR, A
MOV A,P1

BACA_PWD:
CJNE A,#PWD, MATI

NYALA: 
MOV DPTR, #2000H ; jika=1 nyalakan semua LED
MOV A, #0FFH
MOVX @DPTR, A
SJMP BACA_PWD

MATI: 
MOV DPTR, #2000H ; jika=0 matikan semua LED
MOV A, #00H
MOVX @DPTR, A
SJMP BACA_PWD

END

Latihan:
1. Buatlah program seperti pada contoh program 1, output LED menggunakan PC
2. Buatlah program seperti pada contoh program 1, tetapi proses baca input dari PA sedangkan         output LED di P1.
    Petunjuk: Jika PA,PB, PC difungsikan sebagai INPUT maka Control Word (CW) harus diisi           9Bh (lihat tabel 1) Kabel penghubung ke modul disesuaikan terlebih dahulu
3. Buatlah program spt program 1, untuk password: 55h atau 22h


Senin, 23 Desember 2013

PRAKTEK-3 AKSES DATA SECARA LOOK UP TABLE

Posted by Nurvita Abrina On 21.02 | No comments
Langkah:
1. Hubungkan PORT 1 (P1) DT51 MinSysn dengan PORT OUTPUT DT-51 tariner board.
2. Hubungkan CONTROL DT-51 Min Sys dengan CONTROL DT-51 trainer board.
3. Hubungkan DT-51 MinSys dengan PC menggunakan kabel serial
4. Hubungkan Dt-51 MInSys dengansumber tegangan



Teori
Akses data ke alamat memori dapat dilakukan secara berurutan (indeks) dengan melibatkan register DPTR, A dan register pencacah data misal R0.

Contoh:
MULAI:
MOV DPTR,#DATALED ; isi reg DPTR dengan alamat awal data
MOV R0,#00H                   ; siapkan R0 sbdg pencacah data

NEXT: 
CLR A                                ; kosongkan isi reg A
MOVC A,@A+DPTR       ; copy data dari alamat data yg ditunjuk DPTR ke A
-------
INC DPTR                         ; naikkan alamat
INC R0                               ; naikkan pencacah data
CJNE R0,#08h,NEXT       ; apakah cacah data sudah 8, jika belum ke next data


Program I RUNNING LED MANUAL
$mod51
CSEG
ORG 4000H
LJMP START
ORG 4100H

START:
MOV P1,#00000001B
ACALL TUNDA
MOV P1,#00000010B
ACALL TUNDA
MOV P1,#00000100B
ACALL TUNDA
MOV P1,#00001000B
ACALL TUNDA
MOV P1,#00010000B
ACALL TUNDA
MOV P1,#00100000B
ACALL TUNDA
MOV P1,#01000000B
ACALL TUNDA
MOV P1,#10000000B
ACALL TUNDA
LJMP START

TUNDA: MOV R7,#01H
LUP1: MOV R6,#0FFH
LUP2: MOV R5,#0FFH
DJNZ R5,$
DJNZ R6,LUP2
DJNZ R7, LUP1
RET

END

Program 2 RUNNING LED DENGAN LOOP UP TABLE
; PROGRAM AKSES DATA (LOOK UP TABLE)
; AKSES DATA BERURUTAN YANG DI SIMPAN DI TABEL DATA
; DI AKSESES DGN BANTUAN REG DPTR, REG A dan RO
; ==============================================
$MOD51
CSEG
ORG 4000h
LJMP MULAI
ORG 4100h

MULAI: 
MOV DPTR,#DATALED
MOV R0,#00H

NEXT: 
CLR A
MOVC A,@A+DPTR
CPL A
MOV P1,A
INC DPTR
ACALL TUNDA
Praktikum Mikroprosesor, Arif Johar Taufiq., materi dapat didownload di http://guru.technosains.com hal 3
INC R0
CJNE R0,#08h,NEXT
SJMP MULAI

;=======PROSEDUR TUNDA===
TUNDA: MOV R7,#01h
LUP1:      MOV R6,#0FFh
LUP2:      MOV R5,#0FFH
DJNZ R5, $
DJNZ R6,LUP2
DJNZ R7,LUP1
RET

;=======PROSEDUR TUNDA==END
DATALED:
DB 00000001b
DB 00000010b
DB 00000100b
DB 00001000b
DB 00010000b
DB 00100000b
DB 01000000b
DB 10000000b
END

LATIHAN:
1. Buatlah program running LED dengan perintah RR (Rotation Right) dan RL (Ratation Left)       agar LED nyala balak-balik kanan-kiri dan kiri-kanan. Kombinasikan perintah RR, RL dan CJNE untuk mengecek posisi data ujung (80h dan 01h)

Petunjuk:
RR A  geser/rotasi 1 bit isi register A ke Kanan
RL A  geser/rotasi 1 bit isi register A ke Kiri
CJNE A,#80h,TIDAK  apakah isi Reg A=80h, jika tidak maka lompat ke TIDAK, jika YA kerjakan Instruksi dibawahnya


2. Buatlah program running LED bolak balik dengan pola nyala LED yang sudah disimpan di alamat data (DATALED) berarti ada 16 data pola nyala LED. Kerjakan dengan model look up table seperti program 2.


Sumber : guru.technosains.com